You may notice that the regions overlap since they are both filled between their curves and y=0.

And so for your example (done successfully with plot and filled) the region of overlap thus gets rendered with an effect with both specified colors. Both filled regions are constructed by the plot command with a transparency. This produces a darker, purple visual appearance for the lower region (which is all overlap).

And if you added more curves then regions with more overlap would be appear darker still.

If you wish to specify colors for shading the regions between curves separately (without overlap) then you can use the plots:-shadebetween command. This allows you to force the shading to be precisely the colors you specifiy.

For example,

restart;
with(plots):

animate(display,
        ['shadebetween'(sqrt(x), sqrt(x)-1, x=0..t, color="Red"),
         'shadebetween'(sqrt(x)-1, 0, x=0..t, color="Blue"),
        view=[0..20,0..5]], t=0..20);

Here are some things you can try out:

restart;

eq := (1 + a * cos(theta1*x)) * cos(theta2*x) = b:

this := eval(eq, [a=0.25,b=0.1,theta1=2,theta2=24.5]):

this;

       (1 + 0.25 cos(2 x)) cos(24.5 x) = 0.1

#plot( (rhs-lhs)(this), x=0..1 );

fsolve( this, x=0..1 );

                   0.06084048514

fsolve( this, x=0..1, maxsols=10 );

      0.06084048514, 0.1956614960, 0.3171692501, 0.4523388447,
      0.5733212716, 0.7091939827, 0.8293033344, 0.9661987166

You can reduce the size of your expression.

for_transfer_to_word_ac.mw

If that's still too big then you could try splitting it into a sum of terms.

You don't need to construct procedures to do this.

You may find that additional plotting command options can make the results nicer.

u := 1-(8*(10.3968*t^2-5.8368*t*f-.229376*f^2-5.1984))/(4.56*t^2-2.56*t*f+.8192*f^2+2.28)^2:
x := f+t-(8*(-2.28*t+.64*f))/(2.28+2*(-t+.64*f)^2+2.56*t^2):

plot([eval(x,t=0), eval(u,t=0),f=-5..5]);

plot3d([x,t,u], f=-5..5, t=-5..5);
plot3d([x,t,u], f=-5..5, t=-5..5, grid=[251,251]);
plot3d([x,t,u], f=-5..5, t=-5..5, grid=[251,251], style=surface);
plot3d([x,t,u], f=-5..5, t=-5e-1..5e-1, grid=[101,101]);

You should be using left-ticks (single left quotes, a.k.a. name quotes) instead of right-ticks (single right quotes, a.k.a. unevaluation quotes).

Eg,  `-+++` instead of  '-+++'

It appears that (in three places) you wrote else if where you intended what elif would provide instead.

So, as it is, you have too few terminators (and too many stray else instances). Have a look at this recent comment if you don't understand the difference.

I don't understand what assignments you're trying to accomplish. It seems suspicious to me that you are trying to assign to the subscripted h__k in a loop with k as the loop-index. Do you understand the difference between h[k] and h__k (both of which may appear as subscripted in 2D Math)?

I don't see what's wrong with your original suggestion. Eg,

restart;

L := proc(t::realcons, A::list, B::list)
   plots:-display(plottools:-line(A, t*B-(t-1)*A));
end proc:

P, Q := [2,3], [5,-2];
N := 100;

plots:-animate(L, [t, P, Q], t=0..1, paraminfo=false, frames=N);

S := [seq(L(t,P,Q), t=0..1, 1/(N-1))]:
nops(S);

plots:-display(S, insequence);

I may be misunderstanding your request, which is not worded very clearly.

As I read your question, the only points mentioned are the end-points. But you haven't actually stated that you want the animation to consist of plotting points. So above I've connected the two end-points with a (growing, animated) line segment. Please clarify your intention.

In Maple square brackets denote lists, and they do not group terms, ie. they do not indicate mathematical grouping of subexpressions.

So your expectation is invalid, given the role of square brackets in Maple. It works if you remove them.

expr := A*sin(x)^2+A*cos(x)^2;

                        2           2
        expr := A sin(x)  + A cos(x)

simplify(A);

                     A

You can use parentheses (round brackets) to group terms in Maple. None are needed for your example, however. For example the following produces the same expression as above,

A*(sin(x)^2)+A*(cos(x)^2);

                    2           2
            A sin(x)  + A cos(x)

That may be really old Maple, in which a literal dot (ie, . ) was used to denote concatenation.

I haven't modified the whole thing to use the modern LinearAlgebra package instead of the now deprecated linalg package, but here it is using the cat commant instead of that dot.

If you can check whether this is the expected result then we could also revise it to use LinearAlgebra.

Download TransitionMatix_ac.mw

Make sure that you are using indexed names for the subscripting and not literal subscripts.

By that I mean enter them as theta[i] and theta[3] etc. Or use Ctrl-Shift-underscore in 2D Input mode. Don't use the double-underscore theta__i and theta__3, etc or anything from the Layout pallete.

The values of zero that you obtatined make me suspect this might be one of your issues.

You named your procedure RandWalk, so you won't get a plot by calling it wrongly with the name RandomWalk.

Try changing those else if instances into elif .

randomWalk_ac.mw

Your original c and p procedures both return lists, not scalar values. And so your plotting attempt does not match any of the valid calling sequences for the plot command.

If you get rid of the square brackets then they both return scalar values and then plotting is straightforward. Your original call  plot(c(f), f = 50 .. 100)  would also then work.

Download scalar_fcn.mw

restart;
eqs := [a+b+c=10, a/b=b/c, a*b=6]:

Ssol:=[solve(eqs, explicit, allsolutions)]:

remove(has,evalf(Ssol),I);

   [{a = 1.935562295, b = 3.099874421, c = 4.964563284},

    {a = 9.311003375, b = 0.644398865, c = 0.04459776043}]

fsolve(eqs);

     {a = 1.935562277, b = 3.099874424, c = 4.964563299}

fsolve(eqs, {a,b,c}, avoid={fsolve(eqs)});

     {a = 9.311003376, b = 0.6443988642, c = 0.04459776025}

RootFinding:-Isolate(map(rhs-lhs,eqs),[a,b,c]);

  [[a = 9.311003376, b = 0.6443988642, c = 0.04459776025],

   [a = 1.935562277, b = 3.099874424, c = 4.964563299]]

map(u->andmap(is,map(rhs,[simplify(u)[]]),real),Ssol);

               [true, true, false, false]

#select(u->andmap(is,map(rhs,[simplify(u)[]]),real),Ssol);

Are you trying to get the plot of L(T,E) vs E, M(T,E) vs E, and N(T,E) vs E when T is a fixed value such as T=20 or T=200?  Is that supposed to repesent what happens as T gets large? 

Download captive_breeding_ac.mw

[edit] I am aware that the above could be done more efficiently, without repeating some calculuations internally if the L,M,N,P are coupled in the DE. I have it set up this way to make it simpler for the OP -- at least until I can confirm what is actually wanted.)