If tangent lines are perpendicular, then their corresponding radii are perpendicular.  Given three points A, B, C, then AB is perpendicular to BC iff (A[2]-B[2])*(C[2]-B[2]) = (B[1]-A[1])*(C[1]-B[1]).

I also vastly simplified the rest of your code, mostly by using isolve to get the integer points on the circle.

Download Nonperpendicular.mw

Let the expression be expr. Then do

op(indets(expr, specfunc(anything, RootOf))[1]);

Yes, it is easy with plotsetup(window). See help pages ?plot,device and ?plotsetup .

Your question is barely readable. In the future, enter your matrix into Maple and then cut-and-paste the matrix into your post.

I hope that you can draw your conclusions from the following worksheet. If not, ask for more help.

Download Parametric_linear_system.mw

Download Linear_system.mw

Use command residue. For example

residue(1/z, z= 0);

     1

The problem is that you are using m in two different ways. You are using it as an index to the middle add, and you are using it as a procedure. Try this:

t:= exp(2*Pi*I/11);
Mij:= (i,j)-> M[(i mod 11)+1, (j mod 11)+1] ;  
mu:= proc(i,j)
local n,m,k;
     add(add(add(a[k]*a[m]*a[n]*t^m*Mij(i+k-m,j+n-m), n= 0..10), m= 0..10), k= 0..10)
end proc;

Your "New problem" is caused by you trying to return an expression sequence. There is no facility for the return value of a procedure produced by unapply to be an expression sequence. There are two things you can do: (1) Make the return value a list, or (2) Make the return value a list and compose the result with op to convert it back to an expression sequence.

To do (1):

f:= unapply(
      [seq(product(t[j]^'Q[j,i]',j=1..RowDimension(Q)),i=1..ColumnDimension(Q))]
    , seq(t[i],i=1..RowDimension(Q))
);

To do (2):

f:= op@unapply(
      [seq(product(t[j]^'Q[j,i]',j=1..RowDimension(Q)),i=1..ColumnDimension(Q))]
    , seq(t[i],i=1..RowDimension(Q))
);

The solve command should contain variables u and v, not %u and %v.

You can do it like this:

for i in seq(0..100, 0.2), seq(100..0, -0.2) do ... end do;

I will assume that the backslash in your expression should have been a forward slash---that it represents ordinary division. I'll plot a unit sphere in spherical coordinates. So, I am also assuming that you want x and y to range from -1 to 1.

f:= (x,y)-> (5*x^2*y^2-6*x^4)/((1-y^2)*(x^2+y^2)-y^2*(1-x^2-y^2));

plot3d(
     1, theta= 0..2*Pi, phi= 0..Pi,
     color= f(cos(theta)*sin(phi), sin(theta)*sin(phi)),
     coords= spherical, style= patchnogrid, labels= [x,y,z]
);

Make it a single command:

eval(y, isolate(x, D(a)));

Do you want a uniform random selection from all 6-tuples of nonnegative integers whose sum is 8? It can be done like this:

C:= combinat:-composition(8+6, 6):
C[(rand() mod nops(C))+1] -~ 1;

If you want to make such a random selection repeatedly, the above can be made more efficient. Let me know.

Your attempt to trap division-by-zero errors went awry. You set it up so that division by zero returns infinity, but the plots:-circle command doesn't know what to do with infinity as an argument. Your problem can solved by simply filtering out the values that lead to division by zero; there is no need to trap those errors. 

To fix the problem, simply replace the line

d := seq(circle([1, 1/i], 1/i, color = blue), i = -20 .. 20, .1);

with

d:= seq(`if`(i=0, NULL, circle([1, 1/i], 1/i, color= blue)), i= -20 .. 20, .1):

The principles for solving the system of piecewise ODEs are the same as the simplified example above. It is done like this:

Sys1:= EQ||(1..3), op(2, EQ4), op(2, EQ5):
Sys2:= EQ||(1..3), op(4, EQ4), op(4, EQ5):
ICs1:= seq(q||k(0)=0, k= 1..5), seq(D(q||k)(0)=0, k= 1..3):
Sol1:= dsolve({Sys1, ICs1}, numeric, maxfun=0, range= 0..10):
ICs2:= eval(
     [seq(q||k(10) = q||k(t), k= 1..5),
      seq(D(q||k)(10) = diff(q||k(t), t), k= 1..3)
     ], Sol1(10)
)[]:
Sol2:= dsolve({Sys2, ICs2}, numeric, maxfun= 0):
P1:= plots:-odeplot(Sol1, [seq([t, q||k(t)], k= 1..5)], t= 0..10):
P2:= plots:-odeplot(Sol2, [seq([t, q||k(t)], k= 1..5)], t= 10..20):
plots:-display([P1,P2]);