acer

OEIS...

Answered: acer 32328

December 08 2020

0 1

See https://oeis.org/A000399 which gives several formulations, eg.

seq(coeff(expand(mul((x+i),i=1..n)),x,2), n=1..10);

    0, 1, 6, 35, 225, 1624, 13132, 118124, 1172700, 12753576

seq(1/2*n!*(harmonic(n)^2+Psi(1,n+1)-1/6*Pi^2), n=1..10);

    0, 1, 6, 35, 225, 1624, 13132, 118124, 1172700, 12753576

seq((-1)^n*(Stirling1(n+1, 3)), n=1..10);

    0, 1, 6, 35, 225, 1624, 13132, 118124, 1172700, 12753576

Also,

1/2*(Sum(1/i,i = 1 .. n)^2-Sum(1/i^2,i = 1 .. n))*n!

Maple 2015...

Answered: acer 32328

December 08 2020

0 1

That was a problem in Maple 2015, and that particular issue was corrected by Maple 2016.2.

As a kind of workaround you could pass the inert=false option to InertForm:-Display here. I prefer that option because operators get rendered in the usual color of output, rather than in dull gray. For this example the separating brackets get properly shown (though the output appears as implicit multiplication in Maple 2015.2 so it's not quite perfect).

ps. I added the Maple 2015 product marker on your Question, since that's the version in which your atteched worksheet was saved. It might be helpful if you could add that yourself when asking about problems when running in older versions.

misc....

Answered: acer 32328

December 07 2020

2 6

These may be close enough to your goals, that you can adjust to taste.

Download Static_Array_Heat-map_test_ac.mw

one way...

Answered: acer 32328

December 06 2020

2 1

A proper fix consists of teaching Tabulate:-CellHandler and Layout:-Plot about the _DUALAXES plotting substructure and where to find the ROOT substructure within it.

But, for now, this might serve as terse workaround (Maple 2015.2 or Maple 2020.1, say).

>

restart:

>	interface(version)

>	wp := 800: wt := 90: q := plot(x^2, x=0..1, axes=boxed, size=[wp, 400]): p := plot(x, x=0..1, axes=boxed, size=[wp, 400]): r := plots:-display(plots:-dualaxisplot(p, q), size=[wp, 400]): rr := subsop(-1=[op(-1,r),indets(r,specfunc(ROOT))[]][],r):

>	DocumentTools:-Tabulate([rr, p], width=wt):

dualaxes_size_Tabulate.mw

(I will file a bug report.)

aux2...

Answered: acer 32328

December 04 2020

0 1

Your aux2 equation does not look quite right, for your suggested "desired" expression. Or perhaps your "desired" expression is not quite right.

>

restart;

>	eq9_13_m3 := 2R__Rsomega__sL__sigma_S/(s^2L__sigma_S^2omega__s^2 + R__R^2);

2*R__R*s*omega__s*L__sigma_S/(s^2*L__sigma_S^2*omega__s^2+R__R^2)

>	aux2 := s_hat = R__R/(L__sigma_S*omega__s);

s_hat = R__R/(L__sigma_S*omega__s)

>	temp := simplify(eq9_13_m3, {(rhs=lhs)(aux2)}): expand(numer(temp)/s_hat)/(s_hat*expand(denom(temp)/s_hat^2));

2*s/(s_hat*(s^2/s_hat^2+1))

verification

>	desired := 2*(s/s_hat) / (1+(s/s_hat)^2);

2*s/(s_hat*(s^2/s_hat^2+1))

>	simplify( eq9_13_m3 - eval(desired,aux2));

Or perhaps your "desired" expression is not quite right.

>	aux3 := s_hat = R__R/(L__sigma_Somega__ss);

s_hat = R__R/(L__sigma_S*omega__s*s)

>	temp := simplify(eq9_13_m3, {(rhs=lhs)(aux3)}): expand(numer(temp)/s_hat)/(s_hat*expand(denom(temp)/s_hat^2));

2/(s_hat*(1+1/s_hat^2))

Download subst_ex.mw

ideas...

Answered: acer 32328

December 02 2020

3 3

Here are a few ideas for inspiration.

The computation of
n_error[0]:=1.5-newt(1.5);
does not make much sense, if it is intended to mean a comparsion of x[0] and f(x[0]).

The computations of
nerror[count]:=abs(x[count]-x[count-1]);
make sense, but aren't very meaningful as estimates of error in f.

If you have 10 x-values, then you only have 9 incremental changes. There is no first n_error[0] really (or no last one, depending how you want to write it down).

You might want to end the loop if the x-increment gets too small, or if the f(x) evaluation gets acceptably close to zero.

There's not much benefit in storing rt as well as x.

I'm not sure that DataFrames are the best for the task, or at least I'd suggest that the given Append use is a little awkweard. Here's one way with a DataFrame augmented within the loop, and one without.

>

restart;

>	newt := x -> evalf(x - f(x)/D(f)(x)):

>	f:= x -> x^6-2; # function to analyze

>	x[0] := 1.5;

>	xtol,ftol := 1e-10, 1e-10;

>	DF := DataFrame( <<x[0]\|n_error\|f_error>> ): DF[1,2],DF[1,3] := ``, f(x[0]):

>	for count from 1 to 10 do x[count] := newt(x[count-1]); xincr := abs(x[count]-x[count-1]); fval := abs(f(x[count])); DF:=Append(DF,DataSeries(<x[count]\|xincr\|fval>),mode=row); until xincr < xtol or fval < ftol:

>	DataFrame(DF, columns=[x, abs(x_incr), `f `(x)]);

"DataFrame([[[1.5,,9.390625],[1.293895748,0.206104252,2.692407434],[1.170160594,0.123735154,0.567277491],[1.127066579,0.043094015,0.049733650],[1.122508821,0.004557758,0.000500089],[1.122462053,0.000046768,5.0 10^(-8)],[1.122462048,5. 10^(-9),3. 10^(-9)],[1.122462048,0.,3. 10^(-9)]]],rows=[1,2,3,4,5,6,7,8],columns=[x,abs(x_incr),`f `(x)])"

>

restart;
newt := x -> evalf(x - f(x)/D(f)(x)):
f:= x -> x^6-2: # function to analyze
x[0] := 1.5:
xtol,ftol := 1e-10, 1e-10:
M := Array(0..0,1..3,[x[0],"",f(x[0])]):
for count from 1 to 10 do
   x[count] := newt(x[count-1]);
   xincr := abs(x[count]-x[count-1]);
   fval := abs(f(x[count]));
   M(count+1, ..) := <x[count]|xincr|fval>;
until xincr < xtol or fval < ftol:
#M;
W:=DataFrame(Matrix(M), columns=[x, abs(x_incr), ''f''(x)]);

$DataFrame(Matrix(8, 3, {(1, 1) = 1.5, (1, 2) = "", (1, 3) = 9.390625, (2, 1) = 1.293895748, (2, 2) = .206104252, (2, 3) = 2.692407434, (3, 1) = 1.170160594, (3, 2) = .123735154, (3, 3) = .567277491, (4, 1) = 1.127066579, (4, 2) = 0.43094015e-1, (4, 3) = 0.49733650e-1, (5, 1) = 1.122508821, (5, 2) = 0.4557758e-2, (5, 3) = 0.500089e-3, (6, 1) = 1.122462053, (6, 2) = 0.46768e-4, (6, 3) = 0.5000000000e-7, (7, 1) = 1.122462048, (7, 2) = 0.5000000000e-8, (7, 3) = 0.3000000000e-8, (8, 1) = 1.122462048, (8, 2) = 0., (8, 3) = 0.3000000000e-8}), rows = [1, 2, 3, 4, 5, 6, 7, 8], columns = [x, abs(x_incr), f(x)])$

>	Tabulate(W, width=600, widthmode=pixels, weights=[3, 15, 15, 15]):

>

Download newt_DF.mw

name?...

Answered: acer 32328

December 01 2020

1 2

It has to be either a name or a string, since the literal input literal 46th by itself isn't valid Maple syntax for anything. That's also why your string won't parse.

It would be better if you explained clearly what you mean when you write that you want to "get 46th". What do you mean by "get"? Do you mean you want to be able to display something that looks like that, without the double-quotes showing? If so then in what context? Do you mean that you want a Maple expression? What do you mean by 46th, without the string quotes?

Here is one way to obtain it as a name.
convert(46,compose,ordinal,name)
That prints in italics.

The following produces a name that prints in the Standard GUI in upright Roman.
nprintf(`#mn(%a);`,convert(46,ordinal));

one way...

Answered: acer 32328

December 01 2020

1 1

Here is one way. You can either call `k` with a single t-value, or with both a t-value and a new a-value.

After the plotting, you can call `k` at whatever t-values you wish.

>

restart;

>

xodephi := {diff(x(t), t) = 16250.25391*(1 - (487*x(t))/168 + 4*Pi*x(t)^(3/2) + (274229*x(t)^2)/72576 - (254*Pi*x(t)^(5/2))/21 + (119.6109573 - (856*ln(16*x(t)))/105)*x(t)^3 + (30295*Pi*x(t)^(7/2))/1728 + (7.617741607 - 23.53000000*ln(x(t)))*x(t)^4 + (535.2001594 - 102.446*ln(x(t)))*x(t)^(9/2) + (413.8828821 + 323.5521650*ln(x(t)))*x(t)^5 + (1533.899179 - 390.2690000*ln(x(t)))*x(t)^(11/2) + (2082.250556 + 423.6762500*ln(x(t)) + 33.2307*ln(x(t)^2))*x(t)^6)*x(t)^5, diff(xphi(t), t) = 5078.204347*x(t)^(3/2), x(0) = 0.03369973351, xphi(0) = a}: #xphi(10.92469316) = 0}:

>	sol := dsolve(xodephi, parameters=[a], numeric):

>

#
# Calling k(anything, numeric) sets the `a` parameter
# to the second argument.
#
# Calling k(anything, nonnumeric)
#      or k(nonnumeric, anything)
#      or k(nonnumeric)
# returns unevaluated.
#
# Calling k(numeric) computes xphi at that value,
# using the current parameter setting.
#
# Calling k(numeric, numeric) computes xphi at the 1st argument,
# after setting the `a` parameter to the second argument.
#
k := proc(tt, A)
  if nargs=2 then
    if A::numeric and A<>eval(':-a',sol(parameters)) then
      sol(parameters=[A]);
    elif not A::numeric then
      return 'procname'(args);
    end if;
  end if;
  if not tt::numeric then return 'procname'(args); end if;
  eval(xphi(':-t'), sol(tt));
end:

>

>	k(10, 100);

>

k(10);

>	Afound := fsolve(k(10.92469316, A));

>	sol(parameters=[Afound]);

>

k(10);

>	k(10, Afound);

>	#plot( k(10, AA), AA=-500..100, size=[200,200] );

>	plots:-display(Array([ plots:-odeplot(sol, [t,xphi(t)], t=0..11), plots:-odeplot(sol, [t,k(t)], t=0..11, labels=["",xphi]), plot(k(t), t=0..11, labels=["",xphi]) ]), size=[200,200]);

>	seq(k(i), i=0..11.0, 0.5);

>	seq([i, k(i)], i=0..11.0, 0.5);

>

Download ds_param_easy.mw

Import...

Answered: acer 32328

December 01 2020

2 0

Using Maple 2020.1

Download import_url.mw

something...

Answered: acer 32328

December 01 2020

2 4

There are a few different effects.

There's the collecting of terms in the denominator, which I'm guessing is important for you.

And then there's the ordering of terms in products and sums. I'm supposing that you care more about the order of terms in sums, as that can affect whether there are unwanted leading minus-signs.

This is close, except for the order of the multiplicands (X__1-I__11) and (X__2-I__22).

Download simplif_sort_ex.mw

comment...

Answered: acer 32328

November 30 2020

1 3

Download test_units_int_ac.mw

evalf(Int(...))...

Answered: acer 32328

November 30 2020

1 0

Change the evalf(int(...)) calls to evalf(Int(...)) with capitalized Int.

[edit] On my machine that change alone is enough to bring the timing for the cited problematic example down to under 2 seconds. [end of edit]

The lowercase int attempts symbolic integration, and if that fails then wrapping evalf call induce numeric integration. But you may not wish to expend unnecessary effort on the symbolic attempt.

The capitalized Int is an inert placeholder, and evalf(Int(...)) goes directly to an attempt at numeric integration.

normalize, then scale...

Answered: acer 32328

November 30 2020

0 2

You could normalize the vector magnitude (according to the max over the given ranges, say), to get hue values between 0 and 1, and then scale by a factor to avoid the roll-over in the upper end of the hue.

Or you could cook up a similar thing for RGB instead of HSV.

There are other ways, but this could give you some ideas to play with.

>

restart;

>	plots:-fieldplot([1, y^2 + x], x = -10 .. 10, y = -6 .. 6, fieldstrength = fixed, color = COLOR(HSV, 0.833*abs(y^2+x+1)/(36+10+1), 1.0, 1.0));

>	plots:-fieldplot([1, y^2 + x], x = -10 .. 10, y = -6 .. 6, fieldstrength = fixed, color = COLOR(HSV, 0.833*sqrt(((y^2+x)^2+1)/((6^2+10)^2+1)), 1.0, 1.0));

>	huemin:=0.0: huemax:=0.5:

>	plots:-fieldplot([1, y^2 + x], x = -10 .. 10, y = -6 .. 6, fieldstrength = fixed, color = COLOR(HSV, huemin+(huemax-huemin)*sqrt(((y^2+x)^2+1)/((6^2+10)^2+1)), 1.0, 1.0));

>	plot3d(0.833sqrt(((y^2+x)^2+1)/((6^2+10)^2+1)), x = -10 .. 10, y = -6 .. 6, color = COLOR(HSV, 0.833sqrt(((y^2+x)^2+1)/((6^2+10)^2+1)), 1.0, 1.0), labels=[x,y,HUE]);

>

Download color_formula.mw

I included that surface plot3d to illustrate that one of those formulas make it behave something like this:

plot3d(LinearAlgebra:-Norm(<[1,y^2+x]>,2),x=-10..10,y=-6..6,
       colorscheme=["zgradient",[Red,Magenta],colorspace="HSV"]);

And I chose 0.833 for the scaling because that approximates magenta as an upper value for hue.

ColorTools:-Color("HSV", "Magenta")[];
     0.8333333333, 1.000000000, 1.00000000

verify...

Answered: acer 32328

November 30 2020

2 1

Here is one way,

V1 := Vector[column](8, [1,2,2,1,3,A,B,1/(A + B)^2]):
V2 := Vector[column](8, [1,2,2,1,3,A,B,1/(A^2 + 2*A*B + B^2)]):

verify( V1, V2, 'Vector(simplify)' );

                 true

E-Mail Address:
Password:
Remember Me:	Automatically sign in on future visits

E-Mail Address:
Password:
Remember Me:	Automatically sign in on future visits

Ask a Question

Create a Post

32328 Reputation

29 Badges

Social Networks and Content at Maplesoft.com

MaplePrimes Activity

These are answers submitted by acer

OEIS...

not always true...

Maple 2015...

misc....

one way...

aux2...

ideas...

name?...

one way...

Import...

something...

comment...

evalf(Int(...))...

normalize, then scale...

verify...

Save this setting as your default sorting preference?

Ask a Question

Create a Post

Generating PDF…

Save this setting as your default sorting preference?
Note: You can change your preference any time in your account settings
Don't show this again