Apparently it relates to whether the floating-point exponent in a call to `^` matches the type of the base.

It seems to work if the float exponents are cast to complex floats. I got the "expected" result in either of these ways:
1) instead of exponents like 1/beta I used Complex(1/beta,0.0) , and similarly for the others
or,
2) I specified the procedure's parameters alpha and beta as complex(float) rather than float.

I consider this a  bug, and will submit a report

note: I think that your code and operations could be simplified, with several steps combined, etc. I haven't done any of that.

Download Compile_proc_ac.mw

You assigned the result to cSos.

You then tried to call cSoS.

Note the capitalization.

I am surprised that the VolumeOfRevolution command doesn't accept options to specifiy the initial and end angles.

Anyway, for fun,

restart;
with(Student:-Calculus1):
with(plots):
kernelopts(opaquemodules=false):
foo:=eval(VolumeOfRevolution:-ModuleApply):
animate(A->subs(2*Pi=A,eval(foo))(cos(x)+1,x=0..4*Pi,output=plot),
        [A],A=0..2*Pi,paraminfo=false);

Here are attached two more ways.

One uses Explore, since the regular animation frames can be heavy on GUI resources.

Another gets an animated effect by calling Tabulate within a loop. I include this because by various tricks it allows a long 3D plot to be displayed (scaled) without all the usual empty white space above and below.

QuestionAnimationVolumeOfRevolution_ac.mw

The following will export the plot to a file p1.png

You can choose other formats (eg, gif, bmp).

You can utilize the cat command to form the filename (including some location in your filesystem). If you utilize a relative path in the filename, or just a simple filename like the example below, then it will use currentdir() as the base location.

The inline setting puts things back to normal, where plots get displayed in the GUI.

restart;
P:=plot(sin(x),x=0..Pi):
plotsetup(png, plotoutput = "p1.png"):
print(P);
plotsetup(inline):
print(P);

See the Help page for topic plotsetup . And alternative is to use the Export command, which also has a help page with a plotting example.

You don't have to use the use the print command for code at the top-level. But that's what you'd want if running this inside a procedure.

And, of course, you don't also have to output the plot in the GUI as in the last line of the example above (since that's problematic for you).

Whether this solves your problem will depend on whether it really was due only to the inline rendering of the plots.

Up until Maple 2015.2 I get,

  piecewise(1 <= n and n < 10,2^(1-n)*product((-1)^n0*(n0^2+n0-90)/(n0+1),n0 = 1 .. n-1),0)

And from Maple 2016.0 up to Maple 2019.2 I get that unfortunate result.

However,

Download rsolve_hmm.mw

It seems weird, to be calling rsolve with such an assumption.

If I enter the word permute in the Help search then the top result is for the command combinat:-permute.

That returns the permutations of a list.

But that Help pages also has a cross-reference to the parent combinat package, whose page shows links to numbperm, nextperm, etc.

The functionality to specify the format of the float in the labels is a good idea. It would be nice to be able to specify that in the Explore call, for each parameter if relevant. (I will submit a Software Change Request.)

The following surgery on Explore alters the hard-coded numeric formatting for those labels. This might go in your personal initialization file, if it suffices for you. If you really need more flexibility I could make it utilize an environment variable, so that you could adjust it dynamically.

restart;

__KO:=kernelopts(opaquemodules=false):
try
  __KK:=ToInert(eval(Explore:-Runtime:-Update)):
  unprotect(Explore:-Runtime:-Update):
  Explore:-Runtime:-Update:=FromInert(subsop([5,3,4,1,1,2,1,2,3]
    =subs("%.3g"="%.2f",op([5,3,4,1,1,2,1,2,3],__KK)),__KK)):
catch:
  protect(Explore:-Runtime:-Update):
  kernelopts(opaquemodules=__KO):
end try:

Explore(plot(1/10*x^2+a,x=0..10,view=10..23), a=10.5 .. 11.5);

Or you could edit the above to utilize, say, "%.3f" instead of "%.2f", or something else of your choice for the sprintf format string.

Explore_label_format.mw

Of course the optimal solution would be for each parameter's label in each separate exploration to be able to retain its own independent formatting specification.

Download sum_stuff.mw

Are you looking primarily for a way to manually resize (after embedding), or a programmatic way?

The Explore command itself accepts a size option. You haven't mentioned that, so perhaps you are as yet unaware of that? Eg,

    Explore(plot3d(sin(a*x)*y^2,x=-Pi..Pi,y=-1..1),
                  a=1..2.0,size=[600,600]);

The Explore command uses Embedded Components, and in particular it uses a Plot Component to contain the rendered plot. It is true that this component does not have mouse-pointer "resize handles". But you can adjust the width and height properties of that component, after the exploration is embedded in the Worksheet/Document.

For example, using the mouse-pointer, you can do this (Maple 2019), to change the dimension of the Plot Component:
   - Open the context-panel
   - left-click in the plot itself (It has to be within the Plot Component, and not its surroundings. Getting it slightly off will show properties for some surrounding component, which by your description seems to have been key.)
   - Adjust the "Width in pixels" and "Height in Pixels" context-panel

In versions that predate the context-panel you can right-click on the plot and get the context-menu for the Plot Component. Choose Component Properties, and adjust the two relevant fields in the popup. 

[edited] It is true that plot3d does not accept the size option. If it did then Explore would act like it does for the 2D plot command, and utilize that for the dimensions of the component. Indeed, this does work too,

   Resize:=proc(P,m::posint,n::posint)
      op(0,P)(op(P),ROOT(BOUNDS_X(0),BOUNDS_Y(0),
                   BOUNDS_WIDTH(n),BOUNDS_HEIGHT(m)));
   end proc:

    Explore(Resize(plot3d(sin(a*x)*y^2,x=-Pi..Pi,y=-1..1),600,600),
                   a=1..2.0);

That Resize procedure also works for displaying 3D plots outside of Explore. (You could add it to a personal initialization file.)

I came up with a "hot fix" that allows 3D plotting commands to accept the size option. I'll try to find a moment to share it.

In Maple 2019.2 a wrapping pair of (2D Input) single-bars | get parsed as a call to the LinearAlgebra:-Determinant command.

But a wrapping pair of (2D Input) double-bars will get parsed as a call to Norm, according to whether that currently has a binding to, say, LinearAlgebra:-Norm or VectorCalculus:-Norm (which use a different default norm).

I obtain these in 2D Input from the Operator palette.

So, can you get by using the double-bars? Making it work with the single-bars could involve some ugly setup code.

Download Norm_2D.mw

The single left-ticks denote names. The double-quotes denote strings.

Occurrences of cc within a name or a string do not get substituted just because cc has some value (whether a name, string, or whatever).

The commands sprintf and nprintf can be used to format (substitute) a value into a string or a name, respectively. But notice that the characters in a name get rendered in italic, while those within a string appear upright.

for c from 1 to 2 do
  sprintf("the power is %a",c);
  plot( x^c, x= -1..1, title=sprintf("the power is %a",c) )
end do;

for c from 1 to 2 do
  nprintf("the power is %a",c);
  plot( x^c, x= -1..1, title=nprintf("the power is %a",c) )
end do;

You can also use cat or || to concatenate strings or names. Notice that concatenating a string with an integer cc produces another string, and concatenating a name with an integer cc produces another name.

for c from 1 to 2 do
  cat("the power is ",c);
  plot( x^c, x= -1..1, title=cat("the power is ",c) )
end do;
for c from 1 to 2 do
  "the power is "||c;
  plot( x^c, x= -1..1, title="the power is "||c )
end do;
for c from 1 to 2 do
  cat(`the power is `,c);
  plot( x^c, x= -1..1, title=cat(`the power is `,c) )
end do;
for c from 1 to 2 do
  `the power is `||c;
  plot( x^c, x= -1..1, title=`the power is `||c )
end do;

You can also use the special term typeset within the context of most plotting commands to blend strings and math for titles, axis labels, captions, etc. See the Help page for topic plot,typesetting

for c from 1 to 2 do
  plot( x^c, x= -1..1, title=typeset("the power is ",c) )
end do;

Note that the examples above use quotes of some sort to delimit strings (or names containing spaces), and commas to delimit items in a sequence. This is to prevent ambiguity. Simply writing, say, title= the power is c in free form is not valid syntax of the language.

ps. I'm not sure where you saw such use of a period (dot) to denote concatenation. That has not been part of the language for 20 years now.

Here is one way, with a few additional items to also specify the view and tickmarks.

L := [1,2,2,2,3,3,4,4,5,5,6,6]:

Statistics:-Histogram( L, binwidth=1,
                       view=[min(L)-1..max(L)+1,0..0.3],
                       xtickmarks=[$1..max(L)] );

histo.mw

If you would like custom spacing between the column bars you could also use the ColumnGraph command. Eg,

with(Statistics):
L := [1,2,2,2,3,3,4,4,5,5,6,6]:
T := table(Tally(L,output=list),sparse):
S := {L[]}:
LL := [seq(i=T[i]/nops(L),i=min(S)..max(S))]:
ColumnGraph(LL, datasetlabels=none,
            offset=0.625, distance=0.25, width=0.75,
            view=[min(L)-0.625..max(L)+0.625,0..0.3],
            xtickmarks=[seq(i,i=min(S)..max(S))]);

Is this the kind of thing you want?

Download mapleprimes_ac.mw

See the command combinat:-numbpart for the number of partitions of an integer.

When you call fsolve on the multivariate system then it does use Newton's method. See below. You can choose any t value you want below (not just 0 or 1).

You can also obtain explicit solutions in terms of t, symbolically, using solve. These can also be evaluated at specific values of t.

Download RFs.mw