acer

one way...

Answered: acer 32303

February 17 2022

3 0

The colored portions shown by sparsematrixplot are filled polygons, not symbols, ie. it's not a point-plot, which is why passing the symbol option doesn't work for you.

Here's another approach:

>

restart;

>	plots:-setoptions(size=[500,500]):

>	kernelopts(version);

>

H := proc(M::Matrix) local i,m,n,L,V;
  uses LA=LinearAlgebra, IT=ImageTools, P=plots;
  (m,n):=LA:-Dimensions(M):
  (L,V):=((u->[lhs(u)[2],m-lhs(u)[1]+1])~,rhs~)([rtable_elems(M)[]]):
  P:-pointplot(L, style=point, symbol=cross, symbolsize=50,
               color=COLOR(HUE,0.75*IT:-FitIntensity(Array(1..nops(V),1..1,V,
                                                           datatype=float[8]))),
               axis[1]=[tickmarks=[seq(floor(i)=floor(i), i=1..n, (n-1)/4)]],
               axis[2]=[tickmarks=[seq(floor(i)=floor(m-i+1), i=1..m, (m-1)/4)]],
               axes=box, view=[0.5..n+0.5,0.5..m+0.5],
               labels=["column","row"], labeldirections=[horizontal,vertical],
               scaling=constrained, _rest);
end proc:

>	A := Matrix([[2, 1, 0, 0, 3],[0, 2, 1, 0, 0], [0, 0, 2, 1, 0],[0, 0, 0, 2, 1],[0, 0, 0, 0, 2]]);

A := Matrix(5, 5, {(1, 1) = 2, (1, 2) = 1, (1, 3) = 0, (1, 4) = 0, (1, 5) = 3, (2, 1) = 0, (2, 2) = 2, (2, 3) = 1, (2, 4) = 0, (2, 5) = 0, (3, 1) = 0, (3, 2) = 0, (3, 3) = 2, (3, 4) = 1, (3, 5) = 0, (4, 1) = 0, (4, 2) = 0, (4, 3) = 0, (4, 4) = 2, (4, 5) = 1, (5, 1) = 0, (5, 2) = 0, (5, 3) = 0, (5, 4) = 0, (5, 5) = 2})

>	plots:-sparsematrixplot(A, matrixview, color = "Red", scaling=constrained);

>

H(A);

>	B := LinearAlgebra:-RandomMatrix(40,80,generator=0..10,density=0.2):

>	plots:-sparsematrixplot(B, matrixview, color = "Red", scaling=constrained);

>	H(B, symbolsize=8);

>	H(B, symbolsize=8, symbol=solidbox);

>

Download sparse_mat_plot3.mw

Another example:

A := Matrix(100,(i,j)->sin(Pi*(i+j)/20)) *~
     LinearAlgebra:-RandomMatrix(100, generator=1..1,
                                 density=0.1):

H(A, symbolsize=6, symbol=soliddiamond,
  background="#777777", size=[500,500]);

If you do decide that you want just filled polygons rather than symbols -- but colored according to value -- then another approach would be to use the Statistics:-HeatMap command, optionally with a colorscheme option.

It wasn't clear whether you were going to deal with other, larger, Matrices. Once the size gets moderately large (more than 200, say) then switching to a density-style plot using surfdata might be better in terms of GUI performance. And if the size got large (more than 400, say) then switching from a plot to an image might be better.

IterativeMaps...

Answered: acer 32303

February 16 2022

3 0

Here's a way, that has reasonably decent speed to get 500x500 resolution.

It also uses the iteration count to adjust the intensity of the color, retaining a little more information. I like the extra pop it provides. Some alternates approaches are commented out.

The timing is not bad: in total about 4.2 sec for the whole computation on my machine.

But the classifier that matches points to closest root of the polynomial is not optimized, and that step alone takes a 2.2 sec portion of that total! (I couldn't find my old code that did that step better, sorry...)

>

restart:

>	kernelopts(version);

>	with(IterativeMaps): with(ImageTools):

>	#ee := (z^6-1)/(5*z^2+1)^(1/5); ee := z^3-1:

>	st := time[real]():

>	rts:=Vector[row]( sort( [ fsolve(numer(ee),z,complex) ] ), datatype=complex[8]): evalf[8](%);

>	(minr,maxr) := -2,2: (mini,maxi) := -2,2:

>	dee := diff(ee, z): Z := eval( z - ee/dee, z=zr+zi*I):

>	fzi := evalc( Im( Z ) ): fzi := simplify(combine(fzi)) assuming real:

>	fzr := evalc( Re( subs(zi=zit, Z) ) ): fzr := simplify(combine(fzr)) assuming real:

>	N := 500; maxiter := 20; # increasing this will reduce nonconvergence h,w := N, floor(N*(maxr-minr)/(maxi-mini));

>

newt := Escape( height=h, width=w,
                       [zi, zr, zit],
                       [fzi, fzr, zi],
                       [y, x, y], abs(eval(ee,[z=zr+zit*I]))^2<1e-10,
                       minr, maxr, mini, maxi,
                       iterations = maxiter,
                       redexpression = zr, greenexpression = zit, blueexpression=i ):

>	## Use full saturation and full intensity img:=Array(1..h,1..w,1..3,(i,j,k)->1.0,datatype=float[8]):

>	temp:=copy(newt[..,..,3]):

>	## Uncomment either scheme 1 or scheme 2. ## Optional, set intensity to zero for non-convergence. ## scheme 1 #temp:=Threshold(temp,1,low=maxiter+1): #img[..,..,3]:=Threshold(temp,maxiter-1,high=0,low=1):

>	## Optional, set intensity by count (to converge). ## scheme 2 temp:=ln~(map[evalhf](max,temp,1.0)): temp2:=Threshold(temp,0.01,low=1): temp:=zip(`*`,temp,temp2): temp:=FitIntensity(temp): img[..,..,3]:=temp:

>	## Optional, scale the saturation by count (to converge). ## This works as a possible addition to scheme 2. #img[..,..,2]:=1-~img[..,..,3]:

>	## Done inefficiently, set the hue by position in the list of ## all roots. G:=Array(zip((a,b)->min[index](map[evalhf](abs,rts-~(a+bI))), newt[..,..,1],newt[..,..,2]), datatype=float[8],order=C_order): img[..,..,1]:=240FitIntensity(G):

>	final := HSVtoRGB(Flip(img,'vertical')):

>	(time[real]() - st) * 'seconds';

>	Embed(final);

newtbasin2.mw

The above shows an image, in the ImageTools sense. You could turn that into a kind of density-style plot with axes as follows. And you could optionally display this along with a pointplot of the roots, etc. (But note that rendering such high-resolution density-style plots uses a great deal of GUI resources. Embedding images is much gentler on the GUI.)

PLOT(GRID(-2..2,-2..2,Matrix(N,N,datatype=float[8]),
     COLOR(RGB,Rotate(final,-90,degrees))),
     STYLE(PATCHNOGRID),AXESSTYLE(BOX));

Of course one could optionally scale the intensity (brightness) in reverse, so that points which took longer to converge were darker. (That might jibe better with the non-converged points showing as black.)

And here is the same thing, with the option of using the escape-count to adjust the color saturation as well as its intensity.

And here is the other option, using a simpler "scheme 1" for the coloring.

numeric definite integration?...

Answered: acer 32303

February 16 2022

2 0

It looks as if you might be trying to compute the following kind of thing.

(But you might be unclear on the differences between definite and indefinite integration).

>

restart;

>	kernelopts(version);

>	Digits := 15;

>	yyExact := 1/(mc)sqrt((m*c)^2+p^2+q^2);

(c^2*m^2+p^2+q^2)^(1/2)/(m*c)

>	ff11 := cos(k*(p+q+x+t));

>	JJx11 := simplify(combine( QQ/m * Int(p/yyExact * ff11, [p=0..1, q=0..1]) ));

Int(cos(k*p+k*q+k*t+k*x)*QQ*p*c/(c^2*m^2+p^2+q^2)^(1/2), [p = 0 .. 1, q = 0 .. 1])

>	eval(JJx11, [t=0, m=9.11e-31, c=3e8, QQ=1.6e-19, k=0.5, x=0]);

Int(0.48e-10*cos(.5*p+.5*q)*p/(p^2+q^2+0.7469289e-43)^(1/2), [p = 0 .. 1, q = 0 .. 1])

>

evalf(%);

>	# I'm not sure why you were raising Digits as high as 30. Digits := 30; eval(Int(op(JJx11), epsilon=1e-7, method=_CubaCuhre), [t=0, m=9.11e-31, c=3e8, QQ=1.6e-19, k=0.5, x=0]); evalf[7](evalf[30](%)); Digits := 15;

Int(0.48e-10*cos(.5*p+.5*q)*p/(p^2+q^2+0.7469289e-43)^(1/2), [p = 0 .. 1, q = 0 .. 1], epsilon = 0.1e-6, method = _CubaCuhre)

>	simplify(combine( Int(p/yyExact * ff11, [p=0..1, q=0..1]) ));

Int(cos(k*p+k*q+k*t+k*x)*p*m*c/(c^2*m^2+p^2+q^2)^(1/2), [p = 0 .. 1, q = 0 .. 1])

>	eval(%, [t=0, m=9.11e-31, c=3e8, QQ=1.6e-19, k=0.5, x=0]);

Int(0.2733e-21*cos(.5*p+.5*q)*p/(p^2+q^2+0.7469289e-43)^(1/2), [p = 0 .. 1, q = 0 .. 1])

>

evalf(%);

>

Download question11_ac.mw

If you can figure out what kind of integration you really intend then perhaps it's worth investigating why you were raising Digits so high.

And, Or...

Answered: acer 32303

February 14 2022

2 0

Perhaps you're after this kind of functionality,

solve( Or(And(x + y = 2,y = 1,x > 0),And(x^2 = 4, x < 0, y = 0)) );
 
         {x = 1, y = 1}, {x = -2, y = 0}

one way...

Answered: acer 32303

February 12 2022

3 2

Download solve_ex2.mw

map[2]...

Answered: acer 32303

February 11 2022

2 1

This is the same kind of mistake as your other example, and is not a bug.

A successful way is to use map[2], to map applyrule over B using the entire list half_angle_rule as the first argument (ie. passed to applyrule, for each entry in B).

What your orignal code instructs the elementwise operator applyrule~ to do is more like an interleaved zip action.

Download map2_ex2.mw

map[2]...

Answered: acer 32303

February 11 2022

2 1

The error message states the problem. It is not a bug.

You goal appears to be to map applyrule over each of the entries of C, with all of double_angle_rule as the first argument.

The elementwise operator applyrule~ is not correct for doing that. As you wrote it Maple is trying something more like an interleaved zip operation, but the dimensions of C and double_angle_rule do not match.

One way to accomplish the presumed goal is to utilize map[2].

Download map2_ex.mw

That message...

Answered: acer 32303

February 10 2022

3 5

That message (about int being protected) can occur with Grid:-Map in at least in some old versions, eg. Maple 16.

You might pass a user-defined procedure instead, eg.

Download Gr_M16.mw

Tangent...

Answered: acer 32303

February 09 2022

2 2

You could find both tangents to the hyperbola at x=0.504244923, and then select which touches close to y=0.3781836925.

>

restart;

>	(x0,y0) := 0.504244923, 0.3781836925:

>	expr := 7x^2-7y^2-12.0x+9.0y+2.25-2xy:

>	both := Student:-Calculus1:-Tangent~([solve(expr,y)],x=x0):

>	ans := y=~select(t->abs(eval(t,[x=x0])-y0)<1e-5,both)[];

>	plots:-display( plots:-pointplot([[x0,y0]],symbol=solidcircle,symbolsize=15), plot(eval~(y,[ans]),x=-1..2,color=blue), plots:-implicitplot(expr,x=0..2,y=-0.5..1.5), view=[0..2,-0.5..1.5],scaling=constrained,size=[300,300]);

Download hyp_tang.mw

++n, +=...

Answered: acer 32303

February 08 2022

1 1

The Compiler does not know how to handle the syntax ++n and val += FN, and that's where that error message arises.

But it hardly matters, since the Compiler is not aware of combinat:-fibonnacci. You could have that problematic statement "escape" temporarily back to Maple proper, by wrapping in an eval call.

But adjusting the syntax and escaping the combinat:-fibonacci call will not -- in itself -- result in faster performance.

This looks like a contrived example, perhaps constructed to investigate compilation, etc. If so, then it might be better to tell us any other goals in detail.

one liner...

Answered: acer 32303

February 06 2022

2 4

It can be shown to be true (via is and combine) in a 1-line statement for your conditions r>0, r<1. (Also for the wider r>-1, r<1.)

C1 := sqrt(r+1)*sqrt(1/(r-1)):
C2 := -sqrt(r^2-1)/(r-1):

is(combine(C1-C2)=0) assuming r>0, r<1;

             true

is(combine(C1-C2)=0) assuming r>-1, r<1;

             true

note: Such situations in which an extra call to combine (or simplify, say) is needed (in order for is to get the result) are quite rare in my experience. Like obscure corners of lepidopterology. I have reported only a few such, over the years. I'll submit a report for this one too.

various ways...

Answered: acer 32303

February 05 2022

3 0

I prefer solutions in which the "4" does not get rendered in italics (as if it were a name...).

plots:-loglogplot(x, x = 0.1*10^(-5) .. 10,
                  title = 10^Typesetting:-Typeset(-4));

plots:-loglogplot(x, x = 0.1*10^(-5) .. 10,
                  title = 10^(-`#mn(4)`));

plots:-loglogplot(x, x = 0.1*10^(-5) .. 10,
                  title = `#msup(mn("10"),mrow(mo("&uminus0;"),mn("4")));`);

plots:-loglogplot(x, x = 0.1*10^(-5) .. 10,
                  title = InertForm:-Display(`%^`(10,-4),inert=false));

various...

Answered: acer 32303

February 02 2022

2 3

You won't be able to get 23333.33 after rounding to 6 digits, since that requires 7 digits.

Here are a few ways:

>

restart;

>	K := evalf[6](Matrix(3,[1/3,-20/3,-20/3,200/3,70000/3,1.44]));

K := Matrix(3, 3, {(1, 1) = .333333, (1, 2) = -6.66667, (1, 3) = -6.66667, (2, 1) = 66.6667, (2, 2) = 23333.3, (2, 3) = 1.44, (3, 1) = 0., (3, 2) = 0., (3, 3) = 0.})

>	map(x->parse(sprintf("%.2f",x)),K);

Matrix([[.33, -6.67, -6.67], [66.67, 23333.30, 1.44], [0., 0., 0.]])

>	K := evalf[10](Matrix(3,[1/3,-20/3,-20/3,200/3,70000/3,1.44]));

K := Matrix(3, 3, {(1, 1) = .3333333333, (1, 2) = -6.666666667, (1, 3) = -6.666666667, (2, 1) = 66.66666667, (2, 2) = 23333.33333, (2, 3) = 1.44, (3, 1) = 0., (3, 2) = 0., (3, 3) = 0.})

>	new := map(x->parse(sprintf("%.2f",x)),K): new;

Matrix([[.33, -6.67, -6.67], [66.67, 23333.33, 1.44], [0., 0., 0.]])

>	The result here is actually as its displayed. new[1,2]

>	You could also get K printed with the effect. This does not affect the actual values. interface(displayprecision=2): K; interface(displayprecision=-1):

Matrix([[.3333333333, -6.666666667, -6.666666667], [66.66666667, 23333.33333, 1.44], [0., 0., 0.]])

>	A similar effect can be obtained by right-clicking on the following outout and changing its numeric-formatting (in-place) to "Fixed" with 2 decimal places. K;

Matrix(3, 3, {(1, 1) = .33, (1, 2) = -6.67, (1, 3) = -6.67, (2, 1) = 66.67, (2, 2) = 23333.33, (2, 3) = 1.44, (3, 1) = 0., (3, 2) = 0., (3, 3) = 0.})