phephoi := proc (A, B)
local check, i, j, C, E;
uses ListTools;
C := A;
for i from 1 to nops(A) do
   check := 0; 
   for j from 1 to nops(B) do
      if B[j] = A[i] then check := 1; break; end if;
   end do; 
   if check = 0 then C := subsop(Search(A[i],C) = NULL, C); end if;
end do;
C;
end proc:

Example of use:

A := [1, 2, 3, 5, 6, 7];
B := [2, 4, 7, 11, 8];
phephoi(A, B);

If you are interested in the image of a clock face with Maple, look at this post

http://www.mapleprimes.com/posts/143906-Visualization-Of-Clock-And-Degrees-Problem

vv, this is a very elegant solution, vote up!

Here is another solution, based on the procedure named  ArcOnSphere . The procedure draws the shortest arc on a sphere, connecting the specified points (the points do not have to be opposites). Required parameters:  A  and  B  are two points on the sphere, C is the center of the sphere (by default  C = [0, 0, 0] ), G are the graphics options for the space curve  (by default  G=[color=red, thickness=3, scaling=constrained] ).

restart;
ArcOnSphere:=proc(A::list, B::list, C::list:=[0,0,0], G::list(equation):=[color=red, thickness=3, scaling=constrained])
local Av, Bv, Cv, CA, CB, V, M, Phi;
uses Student[LinearAlgebra], plots;
Av, Bv, Cv:= op(convert~([A, B, C], Vector));
CA:=Av-Cv; CB:=Bv-Cv;
V:=CA &x CB;
M:=RotationMatrix(alpha, V);
Phi:=arccos(CA.CB/Norm(CA)/Norm(CB));
spacecurve(M.CA+Cv, alpha=0..Phi, op(G));
end proc:

Example of use:

L:=[[sqrt(3)/2,0,1/2], [0,1/2,sqrt(3)/2], [0,1,0], [1/sqrt(2),1/sqrt(2),0]]:  # 4 points on the unit sphere
L1, L2, L3, L4:=seq(ArcOnSphere(op(L[i..i+1])), i=1..nops(L)-1), ArcOnSphere(L[nops(L)], L[1]):  # The arcs connecting these points
Labels:=["A", "B", "C", "D"]:
T:=plots[textplot3d]([seq([op(L[i]+0.05*L[i]), Labels[i]], i=1..nops(L))], font=[times,bold,16]):
plots[display](L1, L2, L3, L4, T, plottools[sphere](style=surface));

interface(rtablesize=infinity):  # It is necessary that the matrices be displayed explicitly
A, B := LinearAlgebra:-RandomMatrix(15),  LinearAlgebra:-RandomMatrix(15);  # Specifying of two matrices
A+B,  3*A,  A^2,  A.B,  A^(-1);

Please note that for multiplying matrices, we use a dot rather than a sign  "*" 

DuplicationMatrix:=proc(n)
local A, a, L1, L2;
uses ListTools;
A:=Matrix(n, symbol=a, shape=symmetric);
L1:=[seq(seq(A[i,j], j=1..n), i=1..n)];
L2:=convert(L1, set);
Matrix(n^2,n*(n+1)/2, {seq(seq((i,j)=`if`(j=Search(L1[i], L2),1, 0), j=1..n*(n+1)/2), i=1..n^2)});
end proc:

Example of use:
C:=DuplicationMatrix(3);

Check.

A, V1, V2:=<a,b,c; b,d,e; c,e,f>, <a,b,c,d,e,f>, <seq(seq(A[i,j], j=1..3), i=1..3)>;
C.V1=V2;
 

Under the condition that  u, v, delta, lambda, phi, beta, alpha  are in the interval  ]0,1]  there are no solutions.

The proof.

Let   A=(alpha+lambda+u+delta)/(u+v+alpha) ,  B=(alpha+lambda+u+delta)/(u+v)

From the first inequality we have  beta/phi>B  and from the fourth inequality we have  beta/phi<A .  We have a contradiction because  A<B .

Theta:=[ 0, Pi/3, 2*Pi/3, Pi]:
Phi:=[ 0, Pi/3, 2*Pi/3, Pi, 4*Pi/3, 5*Pi/3, 2*Pi, 7*Pi/3]:
F:=(theta,phi)->[cos(phi)*sin(theta), sin(phi)*sin(theta), cos(theta)]:
{seq(seq(F(theta,phi), phi=Phi), theta=Theta)};
A:=plots[pointplot3d](%, color=red, symbol=solidcircle, symbolsize=20):
B:=plottools[sphere]([0,0,0], 1):
plots[display](A, B);

a := [1, 4, 2, 6, 8]:  b:={a[ ]};
{seq(seq(parse(cat(i,j)), j=b minus {i}), i=b)};
select(`<`, b union %, 50);

                 {1, 2, 4, 6, 8, 12, 14, 16, 18, 21, 24, 26, 28, 41, 42, 46, 48}

or using  combinat:-permute  instead of nested  seq  :

a := [1, 4, 2, 6, 8]:  b:={a[ ]};
map(parse@cat@op, combinat:-permute(b,2));
select(`<`, b union {%[ ]}, 50);

Edit.
                     

Apply  evalf  command to your answer.

restart;
with(Student[NumericalAnalysis]):
f:=x->abs(x):
a, b:=-1., 1.:
h:=(b-a)/4:
xx:=[a,a+h,a+2*h,a+3*h,b]:
yy:=map(f, xx):
xy:=zip((u,v)->[u,v], xx, yy);
s2:=CubicSpline(xy, independentvar=x);
P:=expand(Interpolant(s2));
plot([f(x), P], x=-1..1);
Draw(s2);
M:=maximize(abs(abs(x) - P), x=-1..1);

Edit.

restart; 
1 = int(abs(A*exp(-(1/3)*x^2))^2, x = -infinity .. infinity); 
solve({%, A > 0}); 
A := eval(``(A^4)^(1/4), %);   # The final result

Addition. If in the future you are going to do any numerical manipulations with  A , you must first use  expand  command, for example:

evalf(expand(A));

                                  0.6787185469

Examples:

L:=[x1+x2-x3=0, 2*x1-x2+x3=0, x2-3*x3=0]:
convert(L, Vector);
# or
%piecewise(seq(op([``, L[i] ]), i=1..nops(L)));

Addition. You can also display it in a column without any brackets using a for loop:

L:=[x1+x2-x3=0, 2*x1-x2+x3=0, x2-3*x3=0]:
for i from 1 to nops(L) do
L[i];
od;
 

I think the reason is incorrect conversion, which does not need:

int(f(x)*f(y)*x^2*abs(x+y), x=-infinity..infinity, y=-infinity..infinity);
evalf(%);

                                     3/sqrt(Pi)

                                 1.692568750

f:=(x,n)->(1-x^2)^n/n!:
is(diff(f(x,n),x,x) = 2*(1-2*n)*f(x,n-1)+4*f(x,n-2));

                                     true
 

The proof below uses only the initial Maple conversion and  simplest transformations with roots:

Download 111.mw